sihu国产精品永久免费_日韩午夜在线视频_久久99中文字幕伊人_古代男男嗯…啊h总攻

nos001
級別: 探索解密
精華主題: 0
發帖數量: 54 個
工控威望: 110 點
下載積分: 814 分
在線時間: 42(小時)
注冊時間: 2018-03-31
最后登錄: 2022-10-06
查看nos001的 主題 / 回貼
樓主  發表于: 2019-06-27 16:21
圖片：
找不到st編程的教程，硬是自己摸索，一點一點摳出來的。
后來發現iQ-R 結構化文本(ST)編程指南就是教程，關于語法、其他手冊上找不到的較難理解的結構變量都有示例。
完全st編程的中斷寫法好幾天無從著手，把FXCPU結構化順序指令篇看了一遍又一遍，才摸索出來，具體見工程附件。
工程是未完成的不完整工程，只是希望自己認為較難理解手冊沒提及的st編程方法對需要的同志有所幫助。

另外吐槽一下st編輯器，變量不能在程序里定義，只能在標簽窗口定義，結構體成員引用不能單獨設置字體顏色，這些都影響閱讀。
總之，gx works2 的st編輯器比較簡陋，但可閱讀性已經比梯形圖好多了。

復制代碼
  1. (*****************************************************************************************************
  2. * 程序“恒定掃描”設置
  3. * M8039 = TRUE， 則程序為恒定周期掃描
  4. * D8039 = 掃描周期, 單位為ms，最小恒定掃描周期為1ms
  5. *****************************************************************************************************)
  6. M8039 := TRUE;
  7. IF M8039 THEN
  8.     D8039 := 5;
  9. END_IF;
  10. (*****************************************************************************************************
  11. * 初始化
  12. *****************************************************************************************************)
  13. EI ( TRUE );        (* 允許中斷 *)
  15. IF M8002 THEN
  16.     
  17.     FOR j := 0 TO 30 BY 1 DO        
  18.         Tcnt[j] := -1;        
  19.     END_FOR;
  20.     RST( TRUE, HmiKey_ManualOP );
  21.     RST( TRUE, bMode_Manual );
  22.     RST( TRUE, HmiKey_AutoPack );
  23.     RST( TRUE, bMode_Auto );
  24.     DownFill_FB_Call( );
  25.     VerticalSeal_FB_Call( );          
  26.     BagFold_FB_Call( );
  27.     
  28. END_IF;
  30. (* 每包包裝時間所需計數值 = 60000ms / 10ms / 預置包裝速度，每分鐘為60000ms，定時器為10ms *)
  31. TVal_Packing :=  6000 / Param_PresetSpeed;
  33. (*****************************************************************************************************
  34. * 清零
  35. *****************************************************************************************************)
  36. IF( HmiKey_BagCnt_CLR ) THEN
  37.     MakeBagCnt := 0;
  38. END_IF;
  40. IF( HmiKey_PackingCnt_CLR ) THEN
  41.     PackingCnt := 0;
  42. END_IF;    
  44. (*****************************************************************************************************
  45. * 警報發生
  46. * 報警鎖，任何一種警報發生，自動包裝都將停止運行
  47. ****************************************************************************************************)
  48. IF( bAlarm_Lock_AutoPack = TRUE ) THEN
  49.     
  50.     ZRST( TRUE, Y001, Y007 );
  51.     ZRST( TRUE, Y010, Y017 );
  52.     ZRST( TRUE, Y020, Y027 );    
  53.             
  54.     FOR j := 0 TO 30 BY 1  DO        
  55.         Tcnt[j] := -1;        
  56.     END_FOR;    
  57.     
  58. END_IF;
  59. (*****************************************************************************************************
  60. * HMI按鈕開關
  61. *****************************************************************************************************)
  62. Key_Hmi_FB_Call();
  64. (*****************************************************************************************************
  65. * 包裝流程
  66. *
  67. *****************************************************************************************************)
  68. IF( bMode_Auto ) AND ( bAlarm_Lock_AutoPack = FALSE ) AND ( HmiKey_FillPack[1]  OR  HmiKey_EmptyBagTest[1]  OR  HmiKey_FillBagOne[1] ) THEN
  69.     
  70.     IF( HmiKey_FillPack[1]  ) THEN
  71.         DownFill_FB_Call( hmi_key := KeyDownID,  pT_DownFillDly := Tcnt[ ID_DOWN_FILL_DLY ],   iX := iX_DownFill ); (* 下料 *)
  72.     END_IF;
  73.         
  74.     IF( HmiKey_EmptyBagTest[1]  OR  HmiKey_FillBagOne[1] ) THEN
  75.         
  76.         IF( PackingFlow = 0 ) THEN  
  77.                       
  78.             SET( TRUE, bEnd_DownFill );
  79.             PackingFlow := FLOW_PULL_FILM;
  80.                         
  81.         END_IF;
  82.         
  83.     END_IF;
  84.     VerticalSeal_FB_Call( bEnable := bServo_End );    (* 縱封 *)        
  85.     
  86.     BagFold_FB_Call( bEnable:= bServo_End );          (* 折角 *)
  87.     
  88.     ServoControl_FB_Call( pServoEnd := bServo_End  ); (* 伺服拉膜；指針參數，指向全局變量 *)
  89.     
  90.     (* 真空箱閉合 *)
  91.     IF( bServo_End = TRUE ) THEN
  92.         
  93.         IF( Tcnt[ ID_VACUUM_BOX_CLOSE_DLY ] = -1 ) THEN    
  94.             Tcnt[ ID_VACUUM_BOX_CLOSE_DLY ] := Param_VcmBoxCloseDly ;    
  95.         END_IF;
  96.         
  97.         IF( Tcnt[ ID_VACUUM_BOX_CLOSE_DLY ] = 0 )  AND ( bAlarm_GlassDoor = FALSE ) THEN
  98.             
  99.             Tcnt[ ID_VACUUM_BOX_CLOSE_DLY ] := -255;
  100.             Tcnt[ ID_BAG_CUT_DLY ] := Param_CutDly;
  101.             SET( TRUE, Y_VacuumBox_Y3 );            
  102.             
  103.         END_IF;      
  104.           
  105.     END_IF;
  106.     (* 剪切包裝膜 *)
  107.     IF( Y_VacuumBox_Y3 ) THEN
  108.         
  109.         IF( Tcnt[ ID_BAG_CUT_DLY ]  = 0 ) AND ( bAlarm_GlassDoor = FALSE ) THEN
  110.             
  111.             Tcnt[ ID_BAG_CUT_DLY ] := -255;
  112.             Tcnt[ ID_BAG_CUT ] := Param_Cut;
  113.             SET( TRUE, Y_Cutter_Print_cylinder );          
  114.             
  115.         END_IF;    
  116.         
  117.         IF( Tcnt[ ID_BAG_CUT ]  = 0 ) THEN
  118.             
  119.             Tcnt[ ID_BAG_CUT ] := -255;
  120.             Tcnt[ ID_VACUUMIZE ] := Param_Vacuum;
  121.             RST( TRUE, Y_Cutter_Print_cylinder );
  122.             SET( TRUE, Y_VacuumPump_Y5 );
  123.             SET( TRUE, Y_Vacuum_cylinder );
  124.             
  125.         END_IF;    
  126.               
  127.     END_IF;
  128.     (* 包裝袋抽真空、封口，恒溫，冷卻 *)
  129.     IF( Tcnt[ ID_VACUUMIZE ] = 0 ) THEN           (* 抽真空 *)
  130.         
  131.         Tcnt[ ID_VACUUMIZE ] := -255;
  132.         Tcnt[ ID_HEAT_SEAL ] := Param_HeatSeal;
  133.         SET( TRUE, Y_HoriSeal_cylinder );
  134.         
  135.     END_IF;
  136.     
  137.     IF( Tcnt[ ID_HEAT_SEAL ] = 0 ) THEN           (* 熱封 *)
  138.         Tcnt[ ID_HEAT_SEAL ] := -255;
  139.         Tcnt[ ID_SEAL_KEEP ] := Param_SealKeep;
  140.         RST( TRUE, Y_HoriSeal_cylinder );
  141.     END_IF;
  142.     
  143.     IF( Tcnt[ ID_SEAL_KEEP ] = 0 ) THEN           (* 恒溫保持 *)
  144.         Tcnt[ ID_SEAL_KEEP ] := -255;
  145.         Tcnt[ID_SEAL_COOL ] := Param_SealCool;
  146.         SET( TRUE, Y_AirIn_cylinder );
  147.     END_IF;
  148.     
  149.     IF( Tcnt[ID_SEAL_COOL ] = 0 ) THEN            (* 冷卻等待 *)
  150.         RST( TRUE, Y_VacuumBox_Y3 );
  151.         RST( TRUE, Y_Vacuum_cylinder );
  152.         RST( TRUE, Y_AirIn_cylinder );
  153.         PackingFlow := FLOW_END;
  154.     END_IF;
  155.     
  156.     (* 每分鐘為60000ms，程序掃描周期為5ms，每分鐘的計數值為60000 / 5 = 12000 *)
  157.     IF( Cnt < 11999 ) THEN
  158.         Cnt := Cnt + 1;
  159.     END_IF;
  160.         
  161.     IF( PackingFlow = FLOW_END  ) AND ( HmiKey_FillPack[1]  ) THEN
  162.     
  163.         MakeBagCnt := MakeBagCnt + 1;             (* 制袋計數 *)
  164.         PackingCnt := PackingCnt + 1;             (* 包裝計數 *)
  165.         PackingSpeed := 12000 / Cnt;              (* 包裝速度計算 *)
  166.         Cnt := 0;
  167.         
  168.     END_IF;
  169.     
  170.     IF( PackingFlow = FLOW_END ) AND ( HmiKey_EmptyBagTest[1]  OR  HmiKey_FillBagOne[1] )  THEN
  171.         
  172.         MakeBagCnt := MakeBagCnt + 1;             (* 制袋計數 *)
  173.         PackingSpeed := 12000 / Cnt;
  174.         Cnt := 0;
  175.                 
  176.     END_IF;
  178.     (* 包裝流程結束，復位定時器、伺服結束標志、制袋一個按鈕 *)
  179.     IF( PackingFlow = FLOW_END  ) THEN  
  180.         
  181.         PackingFlow := 0;
  182.         RST( TRUE, bServo_End );
  183.         RST( TRUE, HmiKey_FillBagOne[0] );
  184.         FOR j := 0 TO 30 BY 1 DO
  185.             Tcnt[j] := -1;
  186.         END_FOR;
  187.               
  188.     END_IF;
  189.                 
  190. END_IF;
  192. (*****************************************************************************************************
  193. * 包裝膜卷棍電機控制
  194. *
  195. * 說明：接近開關的感應體是一個自由落體的金屬橫桿，由包裝膜拉動其上下運動表示包裝膜的松緊。
  196. *       感應體運動到頂部，頂部金屬感應開關動作，說明包裝膜被拉緊，包裝膜卷棍電機運轉送膜；
  197. *       感應體運動到中部，中部金屬感應開關動作，說明送膜已經足夠，停止送膜；
  198. *       感應體運動到底部，底部金屬感應開關動作，說明接近開關的感應體已經沒有包裝膜拉動其運動，
  199. *       或者送膜太多，感應體自由落體到底部
  200. ****************************************************************************************************)
  201. IF bMode_Auto THEN
  202.     
  203.     IF( ix_PackFilm_SensorTop  ) THEN
  204.         
  205.         SET( TRUE, Y_FilmMotor_Y13 ); (* 送膜 *)
  206.         
  207.     ELSIF( ix_PackFilm_SensorMid OR ix_PackFilm_SensorBot )  THEN
  208.         
  209.         RST( TRUE, Y_FilmMotor_Y13 ); (* 送膜停止 *)
  210.         
  211.     END_IF;  
  212.     
  213. END_IF;
  215. (* 手動控制，放膜 *)
  216. IF HmiKey_ManualOP THEN
  217.     
  218.     IF( HMI手動_放膜 ) THEN
  219.         
  220.         SET( TRUE, Y_FilmMotor_Y13 ); (* 手動送膜 *)
  221.         
  222.     ELSE  
  223.         
  224.         RST( TRUE, Y_FilmMotor_Y13 );    
  225.         
  226.     END_IF;
  227.     
  228. END_IF;
[ 此帖被nos001在2019-07-04 17:38重新編輯 ]
附件： 結構化文本(ST)編程指南-1802.pdf (1477 K) 下載次數:942
網站提示: 請不要用迅雷下載附件，容易出錯
附件： 顆粒包裝機v1.0_ST.gxw.rar (180 K) 下載次數:756
網站提示: 請不要用迅雷下載附件，容易出錯
本帖最近評分記錄：
  • 下載積分:+1(gk1234) 感謝分享！
  • 下載積分:+1(lizhendong) 感謝分享！
  • 下載積分:+1(xn0220xn) 真誠感謝！
  • 下載積分:+1(chihung) 感謝分享！
  • 下載積分:+5(吳工2014)
  • 下載積分:+1(zhcdb2671) 真誠感謝！
  • 下載積分:+3(heidelberg5) 好貼好貼！
    昆山博元電氣
    自動化控制柜、非標設備自動化設計。。。
    級別: 探索解密
    精華主題: 0
    發帖數量: 58 個
    工控威望: 116 點
    下載積分: 2601 分
    在線時間: 15(小時)
    注冊時間: 2019-06-18
    最后登錄: 2020-03-27
    查看昆山博元電氣的 主題 / 回貼
    1樓  發表于: 2019-06-28 22:38
    就可讀性而言，除了個人習慣原因以外，就整體程序并沒有說PLC編程語言有哪一種能完全碾壓另外一種的說法，
    關于梯形圖、結構化還有ST的優劣各大論壇已經討論過很多次了，這跟那個大佬發帖狠懟PLC垃圾，未來發展趨勢是單片機天下
    有異曲同工
    江浙滬非標設備自動化設計制作、自動化控制柜制作及銷售、程序設計...18550928952微信同號
    淘寶店鋪 w2wz.com/grmj